home *** CD-ROM | disk | FTP | other *** search
/ Atari Mega Archive 2 / Atari Mega Archive CD - Volume 2.iso / 8bit / cislib_b / siofix.asm < prev    next >
Assembly Source File  |  1995-04-22  |  3KB  |  66 lines
  1. ;      ---------------------------------------------------------------- 
  2. ;      1027 Printer Timeout Fix  (Ver. 2)                 (AUTORUN.SYS) 
  3. ;      Joe Miller   10 Mar 1985 
  4. ; 
  5. ;      This patch corrects the 1027 printer timeout problem by prevent- 
  6. ;      ing the Operating System from generating an incorrect Data Frame 
  7. ;      checksum.  It consists of two logical modules.  The first module 
  8. ;      is executed once (at initialization) to chain into the "serial 
  9. ;      output ready" IRQ process.  The second module is invoked when an 
  10. ;      IRQ is generated for each serial output byte.  It checks to see 
  11. ;      if an invalid checksum is going to be sent for the current data 
  12. ;      frame, and, if so, prevents it from happening. 
  13. ; 
  14. ;      NOTE:  This code is implemented as a standard "AUTORUN.SYS" file 
  15. ;             so that it may be used with any version of ATARI DOS. 
  16. ;             With some care, it may also be embedded directly within 
  17. ;             your own application program.  Note usage of cassette 
  18. ;             buffer.  Assemble with AMAC. 
  19. ;      ---------------------------------------------------------------- 
  20.  
  21.  
  22. FIXORG EQU     $0480           ; Location of SIO patch 
  23. VSEROR EQU     $020C           ; Serial Output Ready IRQ vector 
  24. CHKSUM EQU     $0031           ; SIO checksum accumulator 
  25. BUFRLO EQU     $0032           ; SIO output buffer pointer 
  26.  
  27.  
  28.        ORG     FIXORG          ; Start SIO patch 
  29.        PHP                     ; Save processor status 
  30.        SEI                     ; Disable IRQs for a moment 
  31.        LDA     VSEROR          ; Save current SIO output ready address 
  32.        STA     UVSER 
  33.        LDA     VSEROR+1 
  34.        STA     UVSER+1 
  35.        LDA     #low SIOFIX     ; Chain our fix into IRQ process 
  36.        STA     VSEROR 
  37.        LDA     #high SIOFIX 
  38.        STA     VSEROR+1 
  39.        PLP                     ; Re-enable interrupts 
  40.        RTS                     ; Return to OS --> 
  41.  
  42. YSAVE  DS      1               ; Temporary for Y-register  
  43. UVSER  DS      2               ; Serial Output Ready IRQ chain address 
  44.  
  45. SIOFIX LDA     CHKSUM          ; For each SIO 'Output Ready' interrupt 
  46.        BNE     SIOJMP          ; If current checksum is zero, then 
  47.        STY     YSAVE           ;    Save Y register 
  48.        LDY     #0              ;    Initialize index 
  49.        LDA     (BUFRLO),Y      ;    Get first buffer byte 
  50.        BEQ     YRESTR          ;    If 1st byte <> 0, then 
  51.        PLA                     ;       This data frame would cause timeout 
  52.        STA     CHKSUM          ;       Save stacked byte in checksum 
  53.        INY                     ;       Bump output buffer index 
  54.        CLC                     ;       'Pre-calculate' corrected checksum 
  55.        LDA     (BUFRLO),Y      ;       Add second byte in output buffer 
  56.        ADC     CHKSUM          ;       To first byte    (already sent) 
  57.        ADC     #0              ;       Including possible carry 
  58.        PHA                     ;       Save it on stack (NOT in CHKSUM!!) 
  59.                                ;    Endif 
  60. YRESTR LDY     YSAVE           ;    Restore Y-register 
  61.                                ; Endif 
  62. SIOJMP JMP     (UVSER)         ; Chain into system's interrupt server 
  63.  
  64.        END     FIXORG          ; End ---------------------------------- 
  65.  
  66.